Hi Craig,

Here’s the macro with comments:

# Number of wavelengths

n_waves = 100



# Starting wavelength [um]

start_wave = 0.70



# Ending wavelength [um]

end_wave = 1.00



# Wavelength range [um]

difference = end_wave - start_wave



# Initialization of array variables

DECLARE wave_array, DOUBLE, 1, n_waves

DECLARE transmission, DOUBLE, 1, n_waves



# Loop over the wavelengths

FOR wave_id, 1, n_waves, 1

    # Actual wavelength [um]

    wavelength = start_wave + (wave_id - 1) * difference / (n_waves - 1)

    

    # Change wavelength in System Parameters

    SYSP 202, 1, wavelength

    

    # Clear all detectors

    clear = NSDD(1, 0, 0, 0)

    

    # Run a raytrace

    NSTR 1, 0, 0, 0, 1, 1, 0

    

    # Save the value-pairs (wavelength vs transmission)

    wave_array(wave_id) = wavelength

    transmission(wave_id) = NSDD(1, 3, 0, 0)

NEXT



# Plot data

PLOT NEW

PLOT TITLE, "Narrowband filter transmission"

PLOT TITLEX, "Wavelength [um]"

PLOT TITLEY, "Transmission [a.u.]"

PLOT RANGEY, 0.0, 1.1

PLOT TICK, 0.05, 0.1

PLOT FORMATX, "%1.2f"

PLOT FORMATY, "%1.1f"

PLOT DATA, wave_array, transmission, n_waves, 16, 0, 0

PLOT GO



# Clear arrays

RELEASE wave_array

RELEASE transmission

There’s a first bit for initialization (before the FOR, NEXT loop), where you can specify the number of wavelengths to evalutae, n_waves, the starting/ending wavelengths in micrometres, start_wave/end_wave. Then, two arrays are initialized, they’ll contain the value pairs wavelength [um] and transmission [-]. In the FOR, NEXT loop, we calculate the wavelength at each iteration and use the SYSP keyword to change it in the System Explorer. Then, we clear all detectors, and run a raytrace, you can change the parameters of NSTR based on this format:

NSTR surf, source, split, scatter, usepolar, ignore_errors, random_seed, save, savefilename, filter, zrd_format

If save and subsequent parameters are ignored, they are simply not used, but I leave it to you to check the Help File for more details.

Finally, after the raytrace, we use the Numeric Function NSDD, which works like the NSDD Merit Function operand, to read the single pixel value of the detector. Since the detector has 1 pixel, and we send 1 ray at 0 degree incidence with 1 watt, we can assume it is like the transmission. If we measure 1 watt, it is transmission = 1.0 and if we measure 0.5 watt, transmission = 0.5, and we plot the graph.

Let me know if this makes sense and if you have any more specific questions.

Take care,

David